# Maintainer: Trần Phát Đạt (Steve Dat) <ttd1232004@gmail.com>
pkgname=vielotus
pkgver=2.0.6
pkgrel=1
pkgdesc="Sen Việt (VieLotusIM) — Next-Gen Vietnamese Input Method for IBus & Fcitx5 (Native C++20 Engine)"
arch=('x86_64' 'aarch64' 'riscv64' 'armv7h' 'i686' 'powerpc64le')
url="https://github.com/stevedat/VieLotus-IM"
license=('MIT')
depends=('glibc' 'gcc-libs' 'glib2' 'python' 'python-gobject' 'gtk3' 'noto-fonts')
makedepends=('cmake' 'extra-cmake-modules' 'pkgconf' 'python' 'fcitx5' 'ibus')
optdepends=(
    'fcitx5-im: Fcitx5 input method framework & GTK/Qt frontends (KDE/Hyprland/XFCE)'
    'ibus: IBus input method framework (GNOME)'
)
provides=('vielotus' 'fcitx5-vielotus' 'ibus-vielotus')
conflicts=('vielotus-bin' 'fcitx5-vielotus' 'ibus-vielotus')
install=vielotus.install

if [ -f "${startdir}/../../../CrossPlatform/capi-native/CMakeLists.txt" ]; then
    source=()
    sha256sums=()
else
    source=("${pkgname}-${pkgver}.tar.gz::https://github.com/stevedat/VieLotus-IM/archive/refs/tags/v${pkgver}.tar.gz")
    sha256sums=('SKIP')
fi

_resolve_srcroot() {
    if [ -f "${startdir}/../../../CrossPlatform/capi-native/CMakeLists.txt" ]; then
        (cd "${startdir}/../../.." && pwd)
    else
        printf '%s/VieLotus-IM-%s\n' "${srcdir}" "${pkgver}"
    fi
}

build() {
    local _srcroot
    _srcroot="$(_resolve_srcroot)"

    cmake -S "${_srcroot}/CrossPlatform/capi-native" -B "${srcdir}/build-core" \
        -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_INSTALL_LIBDIR=lib \
        -DVIELOTUS_INSTALL_DEV=ON
    cmake --build "${srcdir}/build-core"

    cmake -S "${_srcroot}/CrossPlatform/fcitx5-vielotus" -B "${srcdir}/build-fcitx5" \
        -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_INSTALL_LIBDIR=lib \
        -DCMAKE_SKIP_RPATH=ON \
        -DVIELOTUS_LIB_PATH="${srcdir}/build-core/libVieLotusCAPI.so" \
        -DVIELOTUS_INCLUDE_DIR="${_srcroot}/Sources/VieLotusCAPI/include"
    cmake --build "${srcdir}/build-fcitx5"

    cmake -S "${_srcroot}/CrossPlatform/ibus-vielotus" -B "${srcdir}/build-ibus" \
        -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_INSTALL_LIBDIR=lib \
        -DCMAKE_INSTALL_LIBEXECDIR=lib/ibus \
        -DLIBEXECDIR=/usr/lib/ibus \
        -DCMAKE_SKIP_RPATH=ON \
        -DVIELOTUS_LIB_PATH="${srcdir}/build-core/libVieLotusCAPI.so" \
        -DVIELOTUS_INCLUDE_DIR="${_srcroot}/Sources/VieLotusCAPI/include"
    cmake --build "${srcdir}/build-ibus"
}

package() {
    local _srcroot
    _srcroot="$(_resolve_srcroot)"

    DESTDIR="${pkgdir}" cmake --install "${srcdir}/build-core"
    if [ ! -e "${pkgdir}/usr/lib/libVieLotusCAPI.so" ] && [ -e "${pkgdir}/usr/lib/libVieLotusCAPI.so.0" ]; then
        ln -sf libVieLotusCAPI.so.0 "${pkgdir}/usr/lib/libVieLotusCAPI.so"
    fi
    DESTDIR="${pkgdir}" cmake --install "${srcdir}/build-fcitx5"
    DESTDIR="${pkgdir}" cmake --install "${srcdir}/build-ibus"

    if [ -f "${_srcroot}/Resources/typing-modes.yml" ]; then
        install -Dm644 "${_srcroot}/Resources/typing-modes.yml" \
            "${pkgdir}/usr/share/vielotus/typing-modes.yml"
        install -Dm644 "${_srcroot}/Resources/typing-modes.yml" \
            "${pkgdir}/usr/share/vielotus/VietLotusIM_VieLotusCore.resources/typing-modes.yml"
    elif [ -f "${_srcroot}/Sources/VieLotusCore/Resources/typing-modes.yml" ]; then
        install -Dm644 "${_srcroot}/Sources/VieLotusCore/Resources/typing-modes.yml" \
            "${pkgdir}/usr/share/vielotus/typing-modes.yml"
        install -Dm644 "${_srcroot}/Sources/VieLotusCore/Resources/typing-modes.yml" \
            "${pkgdir}/usr/share/vielotus/VietLotusIM_VieLotusCore.resources/typing-modes.yml"
    fi

    install -Dm755 "${_srcroot}/CrossPlatform/packaging/linux/vielotus-settings" \
        "${pkgdir}/usr/bin/vielotus-settings"
    ln -sf vielotus-settings "${pkgdir}/usr/bin/vielotus"
    install -Dm644 "${_srcroot}/CrossPlatform/packaging/linux/vielotus-settings.1" \
        "${pkgdir}/usr/share/man/man1/vielotus-settings.1"
    ln -sf vielotus-settings.1 "${pkgdir}/usr/share/man/man1/vielotus.1"
    install -Dm644 "${_srcroot}/CrossPlatform/packaging/linux/vielotus.desktop" \
        "${pkgdir}/usr/share/applications/vielotus.desktop"
    install -Dm644 "${_srcroot}/CrossPlatform/packaging/linux/org.vielotus.VieLotus.metainfo.xml" \
        "${pkgdir}/usr/share/metainfo/org.vielotus.VieLotus.metainfo.xml"
    for sz in 16x16 24x24 32x32 48x48 64x64 128x128 256x256 512x512; do
        if [ -f "${_srcroot}/CrossPlatform/linux-icons/hicolor_${sz}_apps/vielotus.png" ]; then
            install -Dm644 "${_srcroot}/CrossPlatform/linux-icons/hicolor_${sz}_apps/vielotus.png" \
                "${pkgdir}/usr/share/icons/hicolor/${sz}/apps/vielotus.png"
        fi
    done
    install -Dm644 "${_srcroot}/LICENSE" \
        "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
